(use-modules (gnu)
             (guix)                               ;text-file
             (srfi srfi-26))

(use-package-modules xorg
                     xdisorg                      ;xlockmore, etc.
                     wicd avahi linux tor certs)

(use-service-modules base networking ssh avahi desktop xorg)

(define %my-base-services
  (map (lambda (mservice)
         (mlet %store-monad ((service mservice))
           (if (memq 'nscd (service-provision service))
               (nscd-service (nscd-configuration)
                             #:name-services (list nss-mdns))
               mservice)))
       %base-services))

(operating-system
  (host-name "pluto")
  (timezone "Europe/Paris")
  (locale "en_US.utf8")

  (bootloader (grub-configuration
               (device "/dev/sda")))

  (mapped-devices (list (mapped-device
                         (source "/dev/sda3")
                         (target "home")
                         (type luks-device-mapping))))

  (file-systems (cons* (file-system
                         (device "root")
                         (title 'label)
                         (mount-point "/")
                         (type "ext3"))
                       (file-system
                         (device "/dev/mapper/home")
                         (mount-point "/home")
                         (type "ext3"))
                       %base-file-systems))

  (swap-devices '("/dev/sda4"))                   ;XXX: LABEL=swap
  (name-service-switch %mdns-host-lookup-nss)

  (users (list (user-account
                (name "ludo")
                (comment "Ludovic Courtès")
                (group "users")
                (supplementary-groups '("wheel"   ;sudo
                                        "netdev"  ;wicd
                                        "audio"   ;sound
                                        "video"   ;video4linux, drm, etc.
                                        "cdrom"
                                        "kvm"
                                        "tape"))
                (home-directory "/home/ludo"))))

  (hosts-file
   (plain-file "hosts"
               (string-append (local-host-aliases host-name)
                              %facebook-host-aliases)))

  (services (cons* (slim-service)

                   (avahi-service)
                   (dbus-service (list avahi wicd))
                   (bitlbee-service)
                   (ntp-service)

                   (lsh-service #:root-login? #t)
                   (wicd-service)
                   ;; (dmd-repl-service)

                   %my-base-services))

  (packages (cons* wicd xterm
                   nss-certs                      ;to populate /etc/ssl/certs
                   %base-packages))
  (setuid-programs (cons #~(string-append #$xlockmore "/bin/xlock")
                         %setuid-programs)))